# $Id$

package Apache::AxKit::DirHandler::Basic;
use strict;
use vars qw/@ISA/;
@ISA = ('Apache::AxKit::DirHandler');

use Apache;
use Apache::Log;
use AxKit;
use Apache::AxKit::DirHandler;
use File::Spec;
use Fcntl qw(O_RDONLY LOCK_SH);

sub get_strref {
    my $self = shift;
    local (*DIR);
    my $dir = $self->{directory};
    if (opendir(DIR, $dir)) {
        my $output = '<?xml version="1.0" encoding="UTF-8"?>
<filelist xmlns="http://axkit.org/2002/filelist">
';
        while(my $line = readdir(DIR)) {
            my $xmlline = AxKit::ToUTF8($line);
            $xmlline =~ s/&/&amp;/;
            $xmlline =~ s/</&lt;/;
            my @stat = stat(File::Spec->catfile($dir,$line));
            my $attr = "size=\"$stat[7]\" atime=\"$stat[8]\" mtime=\"$stat[9]\" ctime=\"$stat[10]\"";
            $attr .= ' readable="1"' if (-r _);
            $attr .= ' writable="1"' if (-w _);
            $attr .= ' executable="1"' if (-x _);
            
            if (-f _) {
                $output .= "<file $attr>$xmlline</file>\n";
            } elsif (-d _) {
                $output .= "<directory $attr>$xmlline</directory>\n";
            } else {
                $output .= "<unknown $attr>$xmlline</unknown>\n";
            }
        }
        $output .= "</filelist>\n";
        return \$output;
    }
    return undef;
}

1;
__END__

=head1 NAME

Apache::AxKit::DirHandler::Basic - directory handler implementing a simple XML output

=head1 SYNOPSIS

Override the base DirHandler class and enable it by using:

    AxHandleDirs on
    AxDirHandler Apache::AxKit::DirHandler::Basic

    # or

    AxHandleDirs on
    # This module is the default

=head1 DESCRIPTION

This module is the default Directory Handler when no handler is explicitly
specified.  It is intended to be simple to use and easy to get started with.

=head1 SAMPLE OUTPUT

  <?xml version="1.0" encoding="UTF-8"?>
  <filelist xmlns="http://axkit.org/2002/filelist">
    <directory size="4096" atime="1077320634" mtime="1077312841" ctime="1077312841" readable="1" executable="1">.</directory>
    <directory size="4096" atime="1077316522" mtime="1076743711" ctime="1076743711" readable="1" executable="1">..</directory>
    <file size="0" atime="1076770889" mtime="1076770889" ctime="1076770889" readable="1">index.xml</file>
    <directory size="4096" atime="1076954718" mtime="1076774280" ctime="1076774280" readable="1" executable="1">images</directory>
    <file size="0" atime="1077320634" mtime="1076770894" ctime="1076770894" readable="1">.htaccess</file>
    <file size="580626" atime="1077319951" mtime="1076774007" ctime="1076774007" readable="1">link-4.1a.tar.gz</file>
    <file size="708" atime="1077319951" mtime="1076774018" ctime="1076774018" readable="1" executable="1">Bender.pl</file>
  </filelist>

=head1 SEE ALSO

L<Apache::AxKit::DirHandler>

=cut